vba static array declaration
'VBA arrays can be fixed-size (static) or resizable (dynamic) arrays.
'This is determined when the array is declared:
Dim vArrA() 'dynamic (size is determined later).
Dim vArrB(1 to 5) 'static (size is determined now and cannot be changed).
'Array size refers to the number of elements in the array. For example, vArrB()
'above has five elements.
'VBA is unusual among programming languages with regards to the lowerbound or
'the base, of arrays. Most languages require arrays to have a base (or lowerbound)
'of zero. VBA arrays can have lowerbounds of ANY integer value. So, all of the
'following are valid:
Dim vArrC(0 to 9)
Dim vArrD(1 to 10)
Dim vArrE(11 to 20)
Dim vArrF(-77 to -68)
Dim vArrG(-5 to 4)
'vArrC through vArrG are perfectly legal and each has exactly 10 elements. Note
'that the size AND the bounds are fixed for static arrays. Both of these
'attributes can be changed for dynamic arrays whenever the need arises:
ReDim vArrA(1 to 1000)
'And at a later point:
ReDim vArrA(0 to 4)
'A third attribute of VBA arrays is the number of dimensions. Every example on
'this page thus far represents a 1D array. Another term for a one-dimensional
'array is vector. A vector does not really have rows or columns, just
'elements.
'However, when writing a 1D array to a worksheet, Excel treats the array as if
'it were a 2D array consisting of 1 row and n colums (where n is equal to the
'number of elements). This fact is important and causes confusion for many.
'Consider:
ReDim vArrA(1 to 5)
vArrA(1) = "a"
vArrA(2) = "b"
vArrA(3) = "c"
vArrA(4) = "d"
vArrA(5) = "e"
Sheet1.Range("A1:E5") = vArrA
'Sheet1 now has the following values:
' A B C D E
'1 a b c d e
'2 a b c d e
'3 a b c d e
'4 a b c d e
'5 a b c d e
'This is why Transpose() is required to write the 1D array vertically:
Sheet1.Range("A1:E5") = WorksheetFunction.Transpose(vArrA)
'Sheet1 now has the following values:
' A B C D E
'1 a a a a a
'2 b b b b b
'3 c c c c c
'4 d d d d d
'5 e e e e e
'Notice that the one array with five elements can be written to multiple rows
'or with the Transpose() to multiple columns. Of course, the array can be
'written to one row:
Sheet1.Range("A1:E1") = vArrA
'Or to one column:
Sheet1.Range("A1:A5") = WorksheetFunction.Transpose(vArrA)
'Since Excel treats 1D arrays (vectors) oddly when writing to a worksheet, it
'can be easier to work with 2D arrays. In Excel VBA, 2D arrays are row major.
'This means that rows are represented by the first dimension and columns are
'represented by the second.
ReDim vArrA(1 to 5, 1 to 10)
'vArrA is now sized as a 2D array with 5 rows of 10 columns. It can be written
'to a worksheet with 5 rows of 10 columns without using Transpose().
'This third attribute of VBA arrays... number of dimensions... is also fixed
'in a static array. Size, lower and upper bounds, and number of dimensions
'are all fixed for static arrays and they are all specified when the array is
'declared:
Dim vArrH(0 to 9, 1 to 10)
'vArrH is a static 2D array of 100 elements, 10 rows of 10 columns, with
'0 as the lowerbound for the first dimension (the rows) and 1 as the lowerbound
'of the second dimension (the columns). None of these attributes can later
'be changed for vArrH, since it is a static (or fixed) array. In contrast,
'all three of these attributes can be changed for a dynamic array... at any time.
'The maximum number of dimensions supported for a VBA array is 64, though
'it is unusual to use arrays with more than 3 dimensions. Conceptually, a
'1D array is a vector, a 2D array can be thought of as a worksheet with rows
'and columns, a 3D array can be thought of as a workbook with multiple
'worksheets (or a cube), and a 4D array can be thought of a folder of workbooks
'(or perhaps a hypercube). But keep in mind that each dimension can be declared
'with a different number of elements. For example, a 4D dynamic array:
ReDim vArrA(0 to 4, 1 to 10, 3 to 7, 1 to 2)
' rows , cols , sheets, books
'A fourth attribute of arrays is the data type. The default data type in VBA
'is the Variant. If no data type is specified (as in every example on this
'pages so far) then by default the data type is actually Variant. So all the
'examples so far are Variant arrays, that is an array where every single element
'is of data type Variant.
'Here are some other data type array examples. They can be written verbosely
'or in some cases with a type declaration character:
Dim a() As Variant 'or Dim a()
Dim a() As Double 'or Dim a#()
Dim a() As Single 'or Dim a!()
Dim a() As Short 'or Dim a%()
Dim a() As Long 'or Dim a&()
Dim a() As LongLong 'or Dim a^() <--64bit VBA only
Dim a() As Currency 'or Dim a@()
Dim a() As String 'or Dim a$()
Dim a() As Byte
Dim a() As Date
Dim a() As Boolean
Dim a() As UserDefinedType
Dim a() As ClassName
Dim a() As Object
